'----------- MAKE SURE YOU HAVE THE DATA FILE OPEN

smpl @all

'----------- TAKING LOGS
genr lgdp00q2=log(gdp00q2)

'----------- LINEAR DETRENDING
equation lintrend.ls lgdp00q2=c(1)+c(2)*@trend
genr lgdp00q2_lt=c(1) + c(2)*@trend
genr gap_lt=lgdp00q2-lgdp00q2_lt


'----------- HP FILTERING
lgdp00q2.hpf(lambda=1600) lgdp00q2_hp
genr gap_hp=lgdp00q2-lgdp00q2_hp


'----------- WATSON DETRENDING
'----------- CREATING THE STATE SPACE MODEL
sspace watson
watson.append @signal lgdp00q2 = mu + z
watson.append @state mu = c(11) + mu(-1) + [var=exp(c(12))]
watson.append @state z = c(13)*z(-1) + c(14)*z1(-1) + [var=exp(c(15))]
watson.append @state z1 = z(-1)
'----------- CREATING STARTING INITIAL STATE
vector(3) insta_w=0
insta_w(1) = lgdp00q2(1)
sym(3) invar_w=0
invar_w(1,1)=0.01
invar_w(2,2)=0.01
invar_w(3,3)=0.01
watson.append @mprior insta_w
watson.append @vprior invar_w
'----------- SETTING OPTIMAL START VALUES
watson.append param c(11) 0.008 c(12) -10.5 c(13) 1.42 c(14) -0.45 c(15) -9.7
'----------- ESTIMATE!
watson.ml(showopts)
'----------- MAKE OUTPUT GAP
watson.makestates(t=smooth) *sw
watson.makestates(t=smoothse) *swse
genr gap_w = zsw
genr gap_wp2se=gap_w+2*zswse
genr gap_wm2se=gap_w-2*zswse


'----------- HARVEY-CLARK DETRENDING
'----------- CREATING THE STATE SPACE MODEL
sspace hacla
hacla.append @signal lgdp00q2 = mu + z
hacla.append @state mu = g(-1) + mu(-1) + [var=exp(c(21))]
hacla.append @state g = g(-1) + [var=exp(c(22))]
hacla.append @state z = c(23)*z(-1) + c(24)*z1(-1) + [var=exp(c(25))]
hacla.append @state z1 = z(-1)
'----------- CREATING STARTING INITIAL STATE
vector(4) insta_hc=0
insta_hc(1) = lgdp00q2(1)
sym(4) invar_hc=0
invar_hc(1,1)=0.01
invar_hc(2,2)=0.01
invar_hc(3,3)=0.01
invar_hc(4,4)=0.01
hacla.append @mprior insta_hc
hacla.append @vprior invar_hc
'----------- SETTING OPTIMAL START VALUES
hacla.append param c(21) -10.4 c(22) -17 c(23) 1.44 c(24) -0.51 c(25) -9.8
'----------- ESTIMATE!
hacla.ml(showopts)
'----------- MAKE OUTPUT GAP
hacla.makestates(t=smooth) *shc
hacla.makestates(t=smoothse) *shcse
genr gap_hc = zshc
genr gap_hcp2se=gap_hc+2*zshcse
genr gap_hcm2se=gap_hc-2*zshcse


smpl 1966 1997