'  SIMULTAN.prg: 
'  Schätzung eines simultanen Gleichungssystems (Marktmodell) 
'  mit künstlich generierten Daten
'
'  Gleichungen  q = alfa(1)+alfa(2)*p+alfa(3)*x+u        Nachfrage
'                      q = beta(1)+beta(2)*p+beta(3)*z+v     Angebot

'  Öffnen eines Workfiles und Festlegen des Stichprobenumfangs
	workfile simuldat A 1901 1980

'  Generieren der  Variablen x, z, u und v
   rndseed(type=kn4) 13996   	
	genr x = 10+3*nrnd
	genr z = 5+2*nrnd
	genr u = 1.5*nrnd
	genr v = 2*nrnd
 
'  Festlegung der Parameter
   coef(3) alfa
   coef(3) beta
	alfa(1) = 11
	alfa(2) = -1
	alfa(3) = 1
	beta(1) = 12
	beta(2 )= 0.8
	beta(3) = -0.5

' Definition des Modells
'  Nachfragegleichung nach P aufgelöst 

model markt
markt.append  alfa(2)*p = q - alfa(1) - alfa(3)*x - u
markt.append  q = beta(1) + beta(2)*p + beta(3)*z + v 
			     
' Lösen des Modells für q und p => q_0, p_0
solve markt

' Zuweisung
genr p = p_0
genr q = q_0 

' OLS-Schätzung der beiden Gleichungen
equation eq1.ls q = alfa(1)+alfa(2)*p+alfa(3)*x
equation eq2.ls q = beta(1)+beta(2)*p+beta(3)*z