'  SimAutoCorr.prg:
'  Regression mit künstlich generierten Daten 
'  Schätzung einer Gleichung y = alfa + beta*x + u
'  mit autokorreliertem Störterm u

'  Öffnen eines Workfiles und Festlegen des Stichprobenumfangs
	workfile simpreg Q 1969:4 1996:4

'  Generieren einer erklärenden  Variablen x mit Erwartungswert 0 
'  und Standardabweichung 2
	rndseed(type=kn4) 312
	genr v = nrnd
	genr x = 0
	smpl 1970:1 1996:4
	genr x = 0.707*x(-1)+v

FOR !j = 1 to 100

'  Generieren von y mit einem "wahren Modell" mit den Parametern
'  alfa=4,  beta=2,  sigma=1 und rho = 0.866 
	scalar xseed = 571+!j
	rndseed(type=kn4) xseed
	genr e = nrnd					' sigma=1
	smpl 1969:4 1996:4
	genr u = 0
	smpl 1970:1 1996:4
	genr u = 0.866*u(-1)+e		' rho=0.866
	genr y = 4 + 2*x + u			' alfa=4, beta=2	
	genr u!j = u

	scalar ncoef
	coef(100) alfa
	coef(100) beta
	coef(100) rho
	coef(100) tbeta2
	coef(100) sdbeta 
	coef(100) seofeq 
	coef(100) rquadrat
	coef(100) dw

'  Schätzung der Gleichung: a) oder b) wählen

     ' a) OLS (verzerrt):
      ' equation test!j.ls y = alfa(!j)+beta(!j)*x
      ' ncoef = 2     

     ' b) Transformation nach Cochrane/Orcutt (korrekt)
      equation test!j.ls y = (1-rho(!j))*alfa(!j)+beta(!j)*(x-rho(!j)*x(-1))+rho(!j)*y(-1)
      ncoef = 3

	genr res!j = resid
	sdbeta(!j) = sqr(@covariance(ncoef,ncoef))
	tbeta2(!j) = (beta(!j)-2)/sdbeta(!j)
	seofeq (!j) = @se
	rquadrat(!j) = @r2
	dw(!j) = @dw 

NEXT