'  SIMPREG:
'  Schätzung einer Gleichung  y = alfa + beta*x + u
'  in 1000 künstlich generierten Stichproben mit je 100 Beobachtungswerten 

'  Öffnen eines Workfiles und Festlegen des Stichprobenumfangs
	workfile simpreg U  1 1000

'  Generieren einer erklärenden Variablen x mit Erwartungswert 3 
'  und Standardabweichung 2
	smpl 1 100		' oder: smpl 1 500
	rndseed(type=kn) 76543 
	genr v = nrnd		' oder: genr v = 2*nrnd
	genr x = 3
	smpl 2 100		' oder: smpl 2 500
	genr x = 3+0.7071*(x(-1)-3)+v
	smpl 1 100		' oder: smpl 1 500

'  Initialisieren der Vektoren für Ablage der Schätzresultate
	series(1000) alfa
	series(1000) beta
	series(1000) sdbeta 
	series(1000) tbeta2
	series(1000) seofeq 
	series(1000) rquadrat
	smpl 1 1000

'  Generieren von y mit einem "wahren Modell" mit den Parametern
'  alfa=4,  beta=2  und sigma=1.5 
'  mit 1000 Replikationen

FOR !j = 1 to 1000
	scalar xseed = 8501+!j
	rndseed(type=kn) xseed
	genr u = 1.5*nrnd		' oder: genr u = 3*nrnd
	genr y = 4 + 2*x + u

	' Schätzung der Gleichung
	equation test!j.ls y = c(1)+c(2)*x
	alfa(!j) = c(1)
	beta(!j) = c(2)
	sdbeta(!j) = sqr(@covariance(2,2))
	tbeta2(!j) = (beta(!j)-2)/sdbeta(!j)
	seofeq (!j) = @se
	rquadrat(!j) = @r2
NEXT