'  SIMULTAN100.prg: 
'  Schätzung eines simultanen Gleichungssystems (Marktmodell) 
'  mit künstlich generierten Daten
'  100 mal wiederholt

'  Gleichungen  q = alfa1+alfa2*p+alfa3*x+u        Nachfrage
' 	          q = beta1+beta2*p+beta13*z+v   Angebot

'  Öffnen eines Workfiles und Festlegen des Stichprobenumfangs
	workfile simuldat A 1901 1980

' Initialisierung der Parametervektoren
	coef(100) alfa1
	coef(100) alfa2
	coef(100) alfa3
	coef(100) beta1
	coef(100) beta2
	coef(100) beta3 

	coef(100) alfa1ts
	coef(100) alfa2ts
	coef(100) alfa3ts
	coef(100) beta1ts
	coef(100) beta2ts
	coef(100) beta3ts

' Wahre Parameterwerte
     coef(3) alfa
     coef(3) beta
	alfa(1) = 11
	alfa(2) = -1
	alfa(3) = 1
	beta(1) = 12
	beta(2 )= 0.8
	beta(3) = -0.5

' Definition des Modells
'   Nachfragegleichung nach P aufgelöst 

model markt
markt.append  alfa(2)*p = q - alfa(1) - alfa(3)*x - u
markt.append  q = beta(1) + beta(2)*p + beta(3)*z + v 


FOR !j = 1 to 100

	scalar xseed = 13896+!j
	rndseed(type=kn4) xseed

     ' Generieren der  Variablen x, z, u und v
   	genr x = 10+3*nrnd
	genr z = 5+2*nrnd
	genr u = 1.5*nrnd
	genr v = 2*nrnd

	' Lösen des Modells für q und p => q_0, p_0
	solve markt

	' Zuweisung
	genr p = p_0
	genr q = q_0 

	' OLS-Schätzung der beiden Gleichungen
	equation eq1.ls q = alfa1(!j)+alfa2(!j)*p+alfa3(!j)*x
	equation eq2.ls q = beta1(!j)+beta2(!j)*p+beta3(!j)*z

	' Reduzierte Form für p: phat 
	equation eq3.ls p c x z
	eq3.fit phat

	' TSL-Schätzung der beiden Gleichungen
	equation eq4.ls q = alfa1ts(!j)+alfa2ts(!j)*phat+alfa3ts(!j)*x
	equation eq5.ls q = beta1ts(!j)+beta2ts(!j)*phat+beta3ts(!j)*z
    
NEXT